*Copyright @ www.mycsg.in;

Get the list of variables in a dataset to another dataset

Get the list of variables present in males dataset of work library into a dataset named males_cont01

 
proc contents data=males out=males_cont01 varnum;
run;

Get the list of variables present in females dataset of work library into a dataset named females_cont01

 
proc contents data=females out=females_cont01 varnum;
run;

Get the list of variables present in cars dataset of work library into a dataset named cars_cont01

data cars;
    set sashelp.cars;
run;
 
proc contents data=cars out=cars_cont01 varnum;
run;

Get the list of variables present in datasets named males, females and class of work library into a dataset named cont01

proc contents data=work._all_ out=cont01_pre varnum;
run;
 
data cont01;
    set cont01_pre;
    where memname in ("MALES", "FEMALES", "CLASS");
run;

Get the number of observations present in each dataset of sashelp library into a dataset named numobs

proc contents data=sashelp._all_ out=cont01_pre varnum;
run;
 
proc sort data=cont01_pre out=numobs(keep=libname memname typemem nobs) nodupkey;
    by libname memname typemem nobs;
run;

Get the list of numeric variables present in class dataset of sashelp library into a dataset named cont01_num

data class;
    set sashelp.class;
run;
 
proc contents data=sashelp.class out=cont01_pre;
run;
 
data cont01_num;
    set cont01_pre;
    where type=1;
    keep libname memname name type;
run;

Get the first variable in datasets named class, cars of sashelp library into a dataset named first_vars

proc contents data=sashelp._all_ out=cont01_pre;
run;
 
data cont01;
    set cont01_pre;
    where memname in ("CLASS" "CARS");
run;
 
data first_vars;
    set cont01;
    where varnum=1;
    keep libname memname name varnum;
run;

Identify the list of variables which have a label associated and which do not in sashelp.cars dataset

proc contents data=sashelp.cars out=cont01;
run;
 
data withlabels withoutlabels;
    set cont01;
    if missing(label) then output withoutlabels;
    else output withlabels;
    keep libname memname name label;
run;