*Copyright @ www.mycsg.in;

*==========================================================; *topics to add; *usage of a permanent library to store formats; *usage of fmtsearch option; *usage of nofmterr option; *picture format; *real time scenarios; *==========================================================;

reading input datasets

data class01;
	set sashelp.class;
run;

proc format with defaults

formats catalog gets created if it doesn't already exist in work library

proc format;
run;

Create a user defined format for a character variable

F should appear as Female
M should appear as Male when the format is applied

proc format;
	value $sex
	'F'='Female'
	'M'='Male';
run;
 
data class02;
	set class01;
	format sex $sex.;
run;

Create a format for a numeric variable

 
proc format;
	value teenage
	13='Teen'
	14='Teen'
	15='Teen'
	16-19='Teen'
	low - <13='Pre-teen';
run;
 
data class03;
	set class01;
	format age teenage.;
run;

create an informat for a character variable to read info as character variable

proc format;
	invalue $informat_sex
	'M'='Male'
	'F'='Female'
	;
run;
 
data class04;
	set class01;
	sex_long=input(sex,$informat_sex.);
run;

Create a informat for a character variable to read info as numeric variable

 
proc format;
	invalue informat_num_sex
	'M'=1
	'F'=2;
run;
 
data class05;
	set class01;
	sex_num=input(sex,informat_num_sex.);
run;

Create a dataset from existing formats

library= specifies the library location of formats catalog
by default all the formats and informats present catalog will be exported

proc format cntlout=formats library=work;
run;

Selecting specific formats or informats to export

proc format cntlout=formats02 library=work;
	select $sex @$informat_sex @informat_num_sex teenage;
run;

Display the list (and details) of formats and informats available in a specified catalog

proc format library=work fmtlib;
run;

Picture format for percentages

proc format;
	picture prct (default=7)
	0='9.9)' (prefix="(")
	0<-<100= '09.9)' (prefix="(")
	100='0999)' (prefix="(");
run;

Nine prints zero and zero prints nothing

 
data test;
	percent=0; output;
	percent=1.1; output;
	percent=10.9; output;
	percent=50; output;
	percent=99.9; output;
	percent=100; output;
run;
 
data test2;
	set test;
	length char1 char2 $10;
	char1=put(percent,prct.);
	char2="("||put(percent,5.1)||")"; *(  0.0) vs (0.0);
run;

 
ods listing;
proc report data=test2;
run;
 
proc format;
	picture phone(default=13)
	low-high='999)999-9999' (prefix="(");
run;
 
data phone;
	phone=1234567890;
	char=put(phone,phone.);
run;

*Copyright @ www.mycsg.in;

reading input datasets

SAS Log

proc format with defaults

SAS Log

Create a user defined format for a character variable

SAS Log

Create a format for a numeric variable

SAS Log

create an informat for a character variable to read info as character variable

SAS Log

Dataset View

Create a informat for a character variable to read info as numeric variable

SAS Log

Dataset View

Create a dataset from existing formats

SAS Log

Dataset View

Selecting specific formats or informats to export

SAS Log

Dataset View

Display the list (and details) of formats and informats available in a specified catalog

SAS Log

Picture format for percentages

SAS Log

SAS Log

Dataset View

SAS Log

Dataset View