*Copyright @ www.mycsg.in;

Create an input dataset

We copy `sashelp.class` into a WORK dataset named `class01`
This dataset will be used to demonstrate default and custom summary statistics with PROC MEANS

data class01;
   set sashelp.class;
run;

Inspect `class01` and note that the numeric variables include `age`, `height`, and `weight`
These numeric variables are the default analysis candidates for PROC MEANS

Obtaining descriptive statistics into an output dataset

Question	Answer
How do we specify the input dataset for PROC MEANS?	Use the `data=` option on the PROC MEANS statement.
What happens if we do not provide the data= option?	The most recently created dataset in the current SAS session is used.
How do we specify the variables for which statistics are requested?	Use the `var` statement.
What happens if we do not provide a VAR statement?	SAS produces descriptive statistics for all numeric variables in the input dataset.
How do we specify the output dataset name?	Use the `output` statement with the `out=` option.
What happens if we do not provide the output statement?	No output dataset is created, but summary statistics are still shown in the output window.

Create a dataset named stats01 to store the default descriptive statistics of all numeric variables of class01

We specify the input dataset with `data=class01`
We specify the output dataset with `output out=stats01;`
Because no `var` statement is used, PROC MEANS analyses all numeric variables
The output dataset contains automatic variables such as `_TYPE_`, `_FREQ_`, and `_STAT_`
By default, PROC MEANS produces rows for N, Mean, Std Dev, Minimum, and Maximum

proc means data=class01;
   output out=stats01;
run;

Inspect `stats01` and confirm that each row corresponds to one default statistic
`_STAT_` identifies the statistic represented on that row

Create a dataset named stats02 to store the default statistics of height only

The `var` statement restricts the analysis to the variable `height`
The output dataset contains `height` along with the automatic variables

proc means data=class01;
   var height;
   output out=stats02;
run;

Create a dataset named stats03 to store the default statistics of height and weight

Multiple analysis variables are listed on the same `var` statement separated by spaces
The output dataset contains one column for each requested analysis variable

proc means data=class01;
   var height weight;
   output out=stats03;
run;

Create a dataset named stats04 to store N, Mean, and Median of height

Specific statistics are requested in the `output` statement
Each statistic keyword is followed by an equal sign and the name of the output variable that should store the result
When statistics are named explicitly, the `_STAT_` variable is no longer needed

proc means data=class01;
   var height;
   output out=stats04 n=height_n mean=height_mean median=height_median;
run;

Create a dataset named stats05 to store N, Mean, and Median of height and weight

When more than one analysis variable is listed, the output variable names after each statistic keyword are assigned in the same order
So `height_n` stores N for height and `weight_n` stores N for weight
The same ordering rule applies to the mean and median output variables

proc means data=class01;
   var height weight;
   output out=stats05
      n=height_n weight_n
      mean=height_mean weight_mean
      median=height_median weight_median;
run;

Create a dataset named stats06 to store N, Mean, and Median of age, height, and weight

This example shows that the output variable names do not have to match the input variable names
What matters is the position of each output variable name after the statistic keyword
The first name corresponds to `age`, the second to `height`, and the third to `weight`

proc means data=class01;
   var age height weight;
   output out=stats06
      n=nage nheight nweight
      mean=meanage a101 meanweight
      median=medianage medianheight x101;
run;

In this example `a101` stores the mean of height because height is the second variable on the VAR statement
`x101` stores the median of weight because weight is the third variable on the VAR statement

Create a dataset named stats07 using the AUTONAME option

If the number of variables is large, manually naming every output variable can be tedious
The `autoname` option tells SAS to generate output variable names automatically
SAS combines the analysis variable name and statistic name to create descriptive output names

proc means data=class01;
   var age height weight;
   output out=stats07
      mean=
      median=
      n=
      / autoname;
run;

Create a dataset named stats08 to store N, Mean, and Std of height within each age group

When statistics are needed within groups, we use BY group processing
To use a BY statement, the input dataset must first be sorted by the same BY variable
The output dataset will contain one row per BY group when statistics are explicitly named

proc sort data=class01 out=class01_sort;
   by age;
run;
 
proc means data=class01_sort;
   by age;
   var height;
   output out=stats08 n=height_n mean=height_mean std=height_std;
run;

Inspect `stats08` and confirm that each age value has its own summary row
The variable `age` is carried into the output dataset because it is the BY variable

Create a dataset named stats09 to store N, Mean, and Std of height within each sex group using CLASS

The `class` statement provides grouped summaries without requiring the data to be presorted
Unlike BY processing, CLASS can also produce overall summary rows together with class-level rows
In the output dataset, `_TYPE_` helps identify the summary level represented by each row

proc means data=class01;
   class sex;
   var height;
   output out=stats09 n=height_n mean=height_mean std=height_std;
run;

Review `stats09` and compare it with `stats08` to understand the difference between BY and CLASS processing

Key points to remember

`proc means` calculates descriptive statistics for numeric variables
The `var` statement controls which numeric variables are analysed
The `output` statement creates a SAS dataset containing the results
`autoname` is useful when many output statistic variables must be created
BY and CLASS both support grouped statistics, but they behave differently

*Copyright @ www.mycsg.in;

Create an input dataset

SAS Log

Dataset View

Obtaining descriptive statistics into an output dataset

Create a dataset named stats01 to store the default descriptive statistics of all numeric variables of class01

SAS Log

Dataset View

Create a dataset named stats02 to store the default statistics of height only

SAS Log

Dataset View

Create a dataset named stats03 to store the default statistics of height and weight

SAS Log

Dataset View

Create a dataset named stats04 to store N, Mean, and Median of height

SAS Log

Dataset View

Create a dataset named stats05 to store N, Mean, and Median of height and weight

SAS Log

Dataset View

Create a dataset named stats06 to store N, Mean, and Median of age, height, and weight

SAS Log

Dataset View

Create a dataset named stats07 using the AUTONAME option

SAS Log

Dataset View

Create a dataset named stats08 to store N, Mean, and Std of height within each age group

SAS Log

Dataset View

Create a dataset named stats09 to store N, Mean, and Std of height within each sex group using CLASS

SAS Log

Dataset View

Key points to remember